OnInit

Member of: Any and all scripts.

Event called when the script has been created and all its properties have been initialized.

Syntax

Event OnInit()

Parameters

None

Example

This example uses state switching to run our OnInit code. This method will NOT survive overlapping OnInit events, as seen in many quest structures because OnInit() TWO clears data from OnInit() ONE. See Example 3.

; This is within the "empty" state
Event OnInit() ; This event will run once, when the script is initialized
	GotoState("InitStart")
EndEvent
		
State InitStart
	Event OnBeginState()			
		Debug.Trace("OnInit code started")
		; Do everything we need to here
		GotoState("") ; An empty string represents the "empty state" for scripts.
	EndEvent

	Event OnInit()
	EndEvent
EndState

This script uses an OnUpdate event to run our OnInit code. This method CAN survive overlapping OnInit() but can also fail in some circumstances depending on queue pressure and other factors. See Example 3.

; This is within the "empty" state
Event OnInit() ; This event will run once, when the script is initialized
	RegisterForSingleUpdate(2.0)
EndEvent
		
Event OnUpdate()			
	Debug.Trace("OnInit code started, so stop polling!")
	UnregisterForUpdate()
	; Do everything we need to here
	GotoState("active") ; Switch to a state that doesn't use OnUpdate()
EndEvent

State active
	Event OnUpdate()
		; Do nothing in here.
	EndEvent
EndState

This script generates a randomized entry pins specifically to combat overlapping OnInits, which clear each others old data. If several Inits stack, only the very last entry pin is valid. Keep in mind entropy is the goal, so Entry as string, with random numbers staggered throughout works better. You do NOT need to clear old variables, if an when the quest is reset, they reset themselves. See the Discussion page for more information.

Int _iEntry  ;-Consider this the entry pin

Event OnInit() ;-hits once, and then hits again almost immediately afterwards
	Initialize()
EndEvent

Function Initialize()

    ;-generate random number and STORE to local variable.
	_iEntry = Utility.RandomInt(1000, 99999)
	Int MyEntry = _iEntry
	
    ;-yield here, allow thread 2 to clear thread 1's _iEntry
	Utility.Wait(6.0)
    
    ;-only the last call that entered has valid iEntry after yield
	If (_iEntry == MyEntry)
		Debug.Trace("We're initialized!")
	Else
		Debug.Trace("Rejected bad entry")
	Endif

EndFunction

Notes

• Until OnInit has finished running, your script will not receive any events, and other scripts that try to call functions or access properties on your script will be paused until the event finishes. The only exceptions are when the functions are being called from another script inside its OnInit event, or inside a property set function being set by the master file.
  • As a result, it is generally not advisable to fill your OnInit event with a large amount of processes. It is safer and more reliable to allow your OnInit to finish running while only performing minor tasks, and defer other larger activities to an update (as in the example above) or something similar.
• OnInit is called at the following times:
  • For Quests and Aliases: On game startup, and again whenever the quest starts, due to the quest being reset.
  • For other base objects like Topic Infos, Perks, etc that have scripts that run on the base object: At game start the first time this script is loaded
  • For persistent refs: At game start the first time this script is loaded
  • For non-persistent refs: When the ref is loaded the first time
• OnInit is called again when an object is reset. All your variables and properties will be reset before OnInit is called.
  • For Quests and Aliases this will happen when your quest starts. This means that a quest and alias will see OnInit twice before it starts the first time (game startup, and on reset). This should not cause any problems unless you are manipulating something outside the quest that doesn't reset in your OnInit.
  • For references this happens when the cell resets.
• If a Quest is set to run on game startup and doesn't have the "Run Once" flag ticked, its OnInit event will fire twice when it starts. Ticking the "Run Once" flag, however, prevents the Quest from being reset when it starts, so in this case its OnInit event will only fire once.
• If OnInit is defined within a state, it must also be defined in the empty state (i.e. outside of all explicitly defined states), even if it is not the default state for that script. The definition of OnInit in the empty state can be empty.
• Stacked OnInit() events will clear each others data, with the last one winning. States, bools, properties and variables included, everything is restored to editor defaults.